// $Id: pyr_to_pyr.g,v 16.1 2000/03/02 14:43:39 ajay Exp $
// genesis
// pyr_to_pyr.g  HIPPO model  -GW
// synaptic connections from pyr layer to pyr layer.

/*
 * Usage :
 * planarconnect source-path destination-path
 *		 [-relative]
 *		 [-sourcemask {box,ellipse} x1 y1 x2 y2]
 *		 [-sourcehole {box,ellipse} x1 y1 x2 y2]
 *		 [-destmask   {box,ellipse} x1 y1 x2 y2]
 *		 [-desthole   {box,ellipse} x1 y1 x2 y2]
 *		 [-probability p]
 */

// make_NMDA_conn makes connections from spikegen of pyr cells to NMDA channels of other
// pyr cells. An NMDA connection between a pair of pyr cells is made only if an AMPA
// connection exists between that pair of cells.
// Note: AMPA channel of pyr cell receives SPIKE messages from spikegens of other pyr cells.
//       It also receives one VOLTAGE message from parent (apical) compartment.
  
function make_NMDA_conn
  int cell_num, syn_num
  str src

  for (cell_num=0; cell_num < {CA3_NX*CA3_NY}; cell_num=cell_num+1) // foreach pyr cell
    for (syn_num=0; syn_num < {getsyncount /pyr_layer/pyr[{cell_num}]/apical/AMPA_channel}; \
					syn_num = syn_num+1) // foreach AMPA synapse

	// get source spikegen element
	src = {getsynsrc /pyr_layer/pyr[{cell_num}]/apical/AMPA_channel {syn_num}}

	// addmsg between that source and NMDA channel on current cell
	addmsg {src} /pyr_layer/pyr[{cell_num}]/apical/NMDA_channel SPIKE
    end
   
  end
end

echo Making connections from pyr to pyr....

planarconnect /pyr_layer/pyr[]/soma/spike  \
	      /pyr_layer/pyr[]/apical/AMPA_channel  \
	      -sourcemask box -1 -1  1  1   \
	      -destmask   box -1 -1  1  1   \
	      -probability {p_to_p}

// for above connections, also link spikegens to NMDA channel
make_NMDA_conn

echo Setting weights and delays for pyr to pyr connections....
// assigning delays using the planardelay function

/* 
 * Usage :
 * planardelay path 
 * [-fixed delay]
 * [-radial propagation_velocity] 
 * [-uniform range]   (not used here)
 * [-gaussian sd max] (not used here)
 * [-exp mid max]     (not used here)
 * [-absoluterandom]  (not used here)
 */

planardelay /pyr_layer/pyr[]/soma/spike -radial {CABLE_VEL}

// planardelay /pyr_layer/pyr[]/soma/spike -fixed {p_to_ip_syndelay}

// assigning weights using the planarweight function
/* 
 * Usage :
 *  planarweight sourcepath 
 *          [-fixed weight]
 *          [-decay decay_rate max_weight min_weight]
 *          [-uniform range] 
 *          [-gaussian sd max] 
 *          [-exponential mid max]
 *          [-absoluterandom]
 */

planarweight /pyr_layer/pyr[]/soma/spike -fixed .00001