// $Id: interneuron.g,v 16.1 2000/03/02 14:43:39 ajay Exp $
//genesis

/* This is a CA3 interneuron model based on the equations
** found in R.D. Traub, R. Miles and G. Buzsaki (1992), 
** J. Physiol., 451, 653-672.
**
** Implemented as tabchannels by : Gene Wallenstein
**
** This file depends on functions and constants defined in defaults.g
** Note that the original units used in the paper have been
** converted to SI (MKS) units.  Also, we define the ionic equilibrium 
** potentials relative to the resting potential, EREST_ACT.  In the
** paper, this was defined to be zero.  Here, we use -0.060 volts, the
** measured value relative to the outside of the cell.
*/

// CONSTANTS
float EREST_ACT  = -0.060 /* hippocampal cell resting potl */
float ENA        = 0.115 + EREST_ACT // 0.055
float EK_INT     = -0.025 + EREST_ACT // -0.085
float ECA        = 0.140 + EREST_ACT // 0.080
float SOMA_A_INT = 1.430e-9       // soma area in square meters

/*
For these channels, the maximum channel conductance (Gbar) has been
calculated using the CA3 soma channel conductance densities and soma
area.  Typically, the functions which create these channels will be used
to create a library of prototype channels.  When the cell reader creates
copies of these channels in various compartments, it will set the actual
value of Gbar by calculating it from the cell parameter file.
*/

// The remaining channels are straightforward tabchannel implementations

//========================================================================
//                Tabchannel Na_INT CA3 interneuron channel
//========================================================================
function make_Na_INT
        if ({exists Na_INT})
                return
        end

        create  tabchannel      Na_INT
                setfield        ^       \
                Ek              {ENA}   \                   //      V
                Gbar            { 500 * SOMA_A_INT }    \   //      S
                Ik              0       \                   //      A
                Gk              0       \                   //      S
                Xpower  3       \
                Ypower  1       \
                Zpower  0

        setupalpha Na_INT X {800e3 * (0.0172 + EREST_ACT)}  \
                 -800e3 -1.0 {-1.0 * (0.0172 + EREST_ACT) } -0.004       \
                 {-700e3 * (0.0422 + EREST_ACT) } \
                 700e3 -1.0 {-1.0 * (0.0422 + EREST_ACT) } 5.0e-3 

        setupalpha Na_INT Y 320.0 0.0 0.0  \
                {-1.0 * (0.042 + EREST_ACT)} 0.018  \
                10e3 0.0 1.0 {-1.0 * (0.042 + EREST_ACT) } -5.0e-3 
end

//========================================================================
//                Tabchannel K(DR)_INT CA3 interneuron channel
//========================================================================
function make_K_DR_INT
        if ({exists K_DR_INT})
                return
        end

        create  tabchannel      K_DR_INT
                setfield        ^       \
                Ek              {EK_INT}	\	           //      V
                Gbar            { 250 * SOMA_A_INT }    \          //      S
                Ik              0       \                          //      A
                Gk              0       \                          //      S
                Xpower  4       \
                Ypower  0       \
                Zpower  0

        setupalpha K_DR_INT X {30e3 * (0.0172 + EREST_ACT)}  \
                 -30e3 -1.0 {-1.0 * (0.0172 + EREST_ACT) } -0.005       \
                 450 0.0 0.0 {-1.0 * (0.012 + EREST_ACT) } 0.04 
end