// genesis
// afferent_input.g  HIPPO model  -GW

// Synaptic connections from afferent input to 
// pyramidal cell layer.

// Setting the axonal propagation velocity
float CABLE_VEL = 0.5	// scale factor = 1/(cable velocity) sec/meter

// This function creates an individual synapse.

function makesynapse(pre,post,weight,delay)

	str pre,post
	float weight,delay
	int syn_num
	addmsg {pre} {post} SPIKE
	syn_num={getfield {post} nsynapses} - 1
	setfield {post} synapse[{syn_num}].weight {weight} \
	         synapse[{syn_num}].delay {delay}
end

// Connecting the afferent input to the pyr and int_a cell layers.

function connect_input
echo Connecting the afferent input to the pyramidal cell layer...
echo This will take a minute or two - please be patient....

	int i
	for(i = 0; i <= 24; i = i + 1)
 	   makesynapse /aff_layer/aff[{i}]/input  \
	               /pyr_layer/pyr[{i}]/apical/AMPA_channel \
		       1.0 \
		       1e-4
	end
	for(i = 0; i <= 4; i = i + 1)
 	   makesynapse /aff_layer/aff[{i}]/input  \
	               /int_a_layer/int_a[{i}]/apical/AMPA_channel \
		       1.0 \
		       1e-4

	end
end

connect_input

// This function kills an individual synapse.

function killsynapse(pre)

	str pre
	deletemsg {pre} 0 -out
end

// Kills the stimulus input to the pyramidal cell layer.

function kill_pattern
echo Killing the pattern....
	int i
	for(i = 0; i <= 24; i = i + 1)
	   setfield /aff_layer/aff[{i}]/input rate 0.0
	end

echo O.K., all clear...
end