/* ligand_sampling_boxes.mdl" */

/* Five transparent boxes are created in which to sample free ACh 
and Ch concentration (book Fig. 4.6A).  A box is simply a special 
case of a polygon list object, with 6 quandrangular faces.  By 
definition, boxes are created with the front side of all 6 faces 
on the outside of the box.  Although it is not illustrated here, 
effector sites can be added to box objects just as for polygon 
mesh objects.  In that case, however, each selected box wall is 
automatically bisected to form 2 triangles, each of which then is 
tiled using standard barycentric subdivision.  If the box wall and 
resulting triangles are long and thin, the effector tiles will 
also be long and thin, and visualization of effector sites will 
show molecules in apparent linear arrays.  If, on the other hand, 
triangles and effector tiles are nearly equilateral, visualized 
effector sites will appear realistically positioned in hexagonal 
arrays.  This is one factor to consider in choosing between a 
polygon list and a box object if effector sites will be used (see 
Stiles et al., 2000, for further details). */
sampling_box_1 BOX {
  CORNERS = [ -0.05,-0.015,-0.015 ], [ -0.02,0.015,0.014 ]    /* A 
box is initially defined simply by a "lower-left-front" vertex 
and an "upper-right-back" vertex, and the corresponding 
"FRONT", "BACK", "LEFT", "RIGHT", "TOP", and "BOTTOM" faces 
are filled in and lie parallel to the xz, yz, and xy axis 
planes.  Thereafter, the box template may be scaled, 
translated, and rotated in space to any arbitrary position, 
and one or more faces may be removed. */
  FULLY_CLOSED = YES    /* Would be set to NO if any faces had 
been removed.  Since the box is fully closed, all diffusing 
molecules can be detected as they enter and exit, and this 
allows enclosed molecules to be counted. */
  TRANSPARENT {
    LIGAND = ACh
    ELEMENT = ALL_ELEMENTS
  }
  TRANSPARENT {
    LIGAND = Ch
    ELEMENT = ALL_ELEMENTS
  }
}

sampling_box_2 BOX {
  CORNERS = [ -0.015,-0.06,-0.06 ], [ 0.015,0.06,-0.029 ]
  FULLY_CLOSED = YES
  TRANSPARENT {
    LIGAND = ACh
    ELEMENT = ALL_ELEMENTS
  }
  TRANSPARENT {
    LIGAND = Ch
    ELEMENT = ALL_ELEMENTS
  }
}

/* The contents of the 2 box templates above are copied (multiple 
times) into one metaobject named "all_sampling_boxes", which then 
is instantiated in the main mdl file "rat_nmj.main.mdl". */
all_sampling_boxes OBJECT {
  box_1 OBJECT sampling_box_1 { }    /* "sampling_box_1" above is 
copied as is, i.e., no geometric transformation is applied. */
  box_2 OBJECT sampling_box_1 { TRANSLATE=[0.07,0,0] }    /* 
"sampling_box_1" is copied again and then moved 0.07 microns 
in the direction of the positive x axis to a new position. */
  box_3 OBJECT sampling_box_1 { TRANSLATE=[0.035,0.035,0] }    /* 
copied and moved in the positive x and y directions. */
  box_4 OBJECT sampling_box_1 { TRANSLATE=[0.035,-0.035,0] }    /* 
copied and moved in the positive x and negative y directions. 
*/
  box_5 OBJECT sampling_box_2 { }    /* "sampling_box_2" above is 
copied without geometric transformation. */
  TRANSLATE=[0.0005,0,0.01032]    /* A final adjustment of 
position is applied to all five subobjects. */
}